From ca119c97340caf325cd682c5fdbe8f794a35ac0e Mon Sep 17 00:00:00 2001
From: Sven Gothel <sgothel@jausoft.com>
Date: Tue, 24 Aug 2010 02:39:14 +0200
Subject: Add OpenGL 3.3, 4.0 and 4.1 language mapping.

- Update header:
    - GL/glext.h to khronos 2010-08-03
    - GL3/gl3.h to khronos 2010-08-03

    - Move platform code to
        GL/glplatform.h
        GL3/glplatform.h

    - Unify 64bit typedefs: gl-64bit-types.h

    - Move GL 3.[123] and 4.[01] complete subsumed extension
      enums and functions into their extension spec and just reference them.
      This ensures proper extension availability
      via lower OpenGL profiles, hence a proper GL2GL3 interface.

- GL3/GL4 cleanup:
  - make-glextension-depignore.sh:
    determine required GL version for extensions
    for proper positioning, ie GL2GL3 or GL3 or GL4
    via gluegen IgnoreExtension commands.

  - use ARB_ES2_compatibility for common GL2ES2 methods,
    if available

  - consolidated gl2-gl4 subsumed extension to gl-common.cfg

- Missing GL3/GL4 Functions:
    glMultiDrawElementsBaseVertex
    glDebugMessageCallbackARB
    glDebugMessageCallbackAMD

- TODO (new feature integration):
    - ARB_ES2_compatibility / ARB_get_program_binary for com/jogamp/opengl/util/glsl, ie
        - store binaries com/jogamp/opengl/util/glsl/sdk/CompileShader*
        - query supported binary formats (enums ?)
        - optional prio binaries
    - ARB_ES2_compatibility, if available GLES2/GL2ES12 would be available
    - ARB_separate_shader_objects for com/jogamp/opengl/util/glsl, ie
        - swizzle vertex/fragment shader in programs
        - ..
---
 make/scripts/strip-c-comments.awk | 59 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100755 make/scripts/strip-c-comments.awk

(limited to 'make/scripts/strip-c-comments.awk')

diff --git a/make/scripts/strip-c-comments.awk b/make/scripts/strip-c-comments.awk
new file mode 100755
index 000000000..4f35452b2
--- /dev/null
+++ b/make/scripts/strip-c-comments.awk
@@ -0,0 +1,59 @@
+#!/usr/bin/awk
+
+BEGIN { ORS = "" ; C99=1 }
+
+{ code = code $0 "\n" }
+
+END {
+    while ( length(code) )
+    code = process( code )
+}
+
+function process( text )
+{
+    if ( C99 ) { 
+        if ( match( text, /"|'|\/\*|\/\// ) ) {
+            return span( text )
+        }
+    } else if ( match( text, /"|'|\/\*/ ) ) {
+        return span( text )
+    }
+    print text
+    return ""
+}
+
+function span( text , starter )
+{
+    print substr( text, 1, RSTART - 1 )
+    starter = substr( text, RSTART, RLENGTH )
+    text = substr( text, RSTART + RLENGTH )
+
+    if ( "\"" == starter || "'" == starter ) {
+        return quoted( text, starter )
+    }
+    if ( "//" == starter ) {
+        return remove( text, "\n", "\n" )
+    }
+    ## Allow for
+    ## /* foo *\
+    ## /
+    return remove( text, "\\*(\\\\\n)?/", " " )
+}
+
+function remove( text, ender, replacement )
+{
+    print replacement
+    return substr( text, match(text, ender) + RLENGTH )
+}
+
+function quoted( text, starter )
+{
+    if ( "'" == starter ) {
+        match( text, /^(\\.|[^'])*'/ )
+    } else {
+        match( text, /^(\\.|\?\?\/.|[^"])*"/ )
+    }
+    print starter substr( text, 1, RLENGTH )
+    return substr( text, RSTART + RLENGTH )
+}
+
-- 
cgit v1.2.3